Example of polytope on plane

Show[ContourPlot3D[x+y+z==10,{x,-10,15},{y,-15,10},{z,-10,15},Mesh->None,BoundaryStyle->None,AxesLabel->{"x","y","z"}],RegionPlot3D[ 5x-y-4z≤32 && -8x-17y+25z≤172 && -4x+7y-3z≤24,{x,-10,15},{y,-15,10},{z,-10,15},Mesh->None,LabelStyle->(FontSize->14),PlotPoints->50,PlotStyle->Directive[GrayLevel[1/10,1/10]],BoundaryStyle->None]]

Find vertices of polytope

Solve[{x+y+z==10,5x-y-4z==32, -8x-17y+25z==172 },{x,y,z}]

Solve[{x+y+z==10,5x-y-4z==32,-4x+7y-3z==24 },{x,y,z}]

Solve[{x+y+z==10, -8x-17y+25z==172,-4x+7y-3z==24 },{x,y,z}]

feasibleset=Show[ContourPlot3D[x+y+z==10,{x,-10,15},{y,-15,10},{z,-10,15},Mesh->None,BoundaryStyle->None,AxesLabel->{"x","y","z"}],Graphics3D[Polygon[{{10,-6,6},{6,6,-2},{-4,5,9}}]]]

Level curves of objective function

Manipulate[Show[feasibleset,ContourPlot3D[-5x+y+4z==k,{x,-10,15},{y,-15,10},{z,-10,15},Mesh->None,BoundaryStyle->None,ContourStyle->Directive[Blue
,Opacity[0.5]]]],{k,-80,80}]

Example where optimal set is an edge

Manipulate[Show[feasibleset,ContourPlot3D[6x-y+2z+5==k,{x,-10,15},{y,-15,10},{z,-10,15},Mesh->None,BoundaryStyle->None,ContourStyle->Directive[Blue
,Opacity[0.5]]]],{k,-20,100}]

One-norm minimization

Manipulate[ContourPlot[{Abs[x]+Abs[y]==k,x+4y==5},{x,-3,3},{y,-3,3}],{k,0,2}]

Two-norm minimization

Manipulate[ContourPlot[{x^2+y^2==k,x+4y==5},{x,-3,3},{y,-3,3}],{k,0,2}]

Regression example: best fit line to points {0,0},{1,8},{3,8},{4,20}

A={{0,1},{1,1},{3,1},{4,1}};
b={0,8,8,20};
x=LinearSolve[Transpose[A].A,Transpose[A].b]

Show[Plot[4x+1,{x,-1,5}],ListPlot[{{0,0},{1,8},{3,8},{4,20}}]]

Plot3D[Abs[c]+Abs[m+c-8]+Abs[3m+c-8]+Abs[4m+c-20],{m,0,10},{c,-1,1},AxesLabel->{"m","c","z"},PlotPoints->100]

Plot3D[Abs[c]+Abs[m+c-8]+Abs[3m+c-8]+Abs[4m+c-20],{m,4,6},{c,-1,1},AxesLabel->{"m","c","z"},PlotPoints->100]

Minimize[Abs[c]+Abs[m+c-8]+Abs[3m+c-8]+Abs[4m+c-20],{m,c}]

Show[Plot[5x+0,{x,-1,5}],ListPlot[{{0,0},{1,8},{3,8},{4,20}}]]