This takes 2.7.6 and goes beyond what the exercise asks for, in order to demonstrate how to plot a neat bifurcation using Mathematica.

f[x_,r_]:=r+x-x^3;
V[x_,r_]:=-r x-x^2/2+x^4/4;

Plot[V[x,0],{x,-2.3,2.3},PlotStyle->{Black, Thickness[0.01]},AxesLabel->{x,V}]

Plot[V[x,1],{x,-2.3,2.3},PlotStyle->{Black, Thickness[0.01]},AxesLabel->{x,V}]

Plot[V[x,-1],{x,-2.3,2.3},PlotStyle->{Black, Thickness[0.01]},AxesLabel->{x,V}]

fixedpts=Solve[f[x,r]==0,x]

dfdx=D[f[x,r],x];
criticalpts=Solve[{f[x,r]==0,dfdx==0},{x,r}]

Simplify[fixedpts/.r->-(2/(3 (Sqrt[3])))]

Simplify[fixedpts/.r->(2/(3 (Sqrt[3])))]

There are three fixed points if -(2/(3 (Sqrt[3])))< r <(2/(3 (Sqrt[3]))) (imaginary parts of the expressions will cancel).
If r = -(2/(3 (Sqrt[3]))) or r = (2/(3 (Sqrt[3]))), then there are two fixed points.  Otherwise, there is only one fixed point.

UnstableBranch=ContourPlot[r+x-x^3==0,{r,-(2/(3 (Sqrt[3]))),(2/(3 (Sqrt[3])))},{x,-(1/(Sqrt[3])),(1/(Sqrt[3]))},ContourStyle->{Gray,Dashing[{.02,.03}],Thickness[.01]},AxesLabel->Automatic]

UpperStableBranch=ContourPlot[r+x-x^3==0,{r,-(2/(3 (Sqrt[3]))),1},{x,(1/(Sqrt[3])),1.32},ContourStyle->{Black,Thickness[.01]}]

LowerStableBranch=ContourPlot[r+x-x^3==0,{r,-1,(2/(3 (Sqrt[3])))},{x,-1.32,-(1/(Sqrt[3]))},ContourStyle->{Black,Thickness[.01]}]

Bifurcation diagram

Show[UnstableBranch,UpperStableBranch,LowerStableBranch,PlotRange->All]